# NEOTICKER DATA BEGIN
ScriptType=Indicator
Description=SlowK Swing Trading System
Name=sys_slowk_eod
Language=Formula
Links=1
MinBars=0
TimerInterval=100
MetaStyle=Normal
ValueRange=Same as Source
Placement=Smart
Multiplot_num_plots=1
Multiplot_color_0=255
Multiplot_style_0=Line
Multiplot_width_0=1
Multiplot_enabled_0=1
Multiplot_breakstyle_0=0
UpdateByTick=0
TradingSystemUI=1
PrimaryLinkOnly=0
NotifyOnRemoval=0
Param_count=7
Param_name_0=FastK
Param_inuse_0=1
Param_type_0=integer.gt.0
Param_default_0=5
Param_name_1=SlowK
Param_inuse_1=1
Param_type_1=integer.gt.0
Param_default_1=3
Param_name_2=OS Level
Param_inuse_2=1
Param_type_2=real
Param_default_2=25
Param_name_3=OB Level
Param_inuse_3=1
Param_type_3=real
Param_default_3=75
Param_name_4=Swing Period
Param_inuse_4=1
Param_type_4=integer.gt.0
Param_default_4=5
Param_name_5=Percent Equity
Param_inuse_5=1
Param_type_5=real
Param_default_5=100
Param_name_6=Round Lot
Param_inuse_6=1
Param_type_6=integer
Param_default_6=100
Explanation_Lines=0
# NEOTICKER DATA END

' SlowK Swing Trading System
' Written by Lawrence Chan
' All rights reserved

plot1 := currentequity;

makeindicator (myslowk, slowk, data1, param1, param2);

$pct_equity := currentequity * param6 / 100;

$next_size :=
   if (param6 = 0,
       defaultordersize,
       int ($pct_equity / data1 / param7) * param7) ;

bars_since_long :=
   if (openpositionlong <= 0, 0, 1 + bars_since_long (1));

longatmarket (
   openpositionlong <= 0
   and xbelowconst (myslowk, param3) > 0,
   $next_size);

$exit_condition := myslowk > param4;

longexitatmarket (
   $exit_condition,
   openpositionabssize);

longexitatmarket (
   $exit_condition <= 0
   and bars_since_long >= param5,
   openpositionabssize);